Transformer (Equivalent Circuit Model)

Old Content - visit altium.com/documentation

Model Kind

General

Model Sub-Kind

Spice Subcircuit

SPICE Prefix

X

SPICE Netlist Template Format

@DESIGNATOR %1 %2 %3 %4 @MODEL #|PARAMS:| ?RATIO|RATIO=@RATIO| ?RP|RP=@RP| ?RS|RS=@RS| ?LEAK|LEAK=@LEAK| ?MAG|MAG=@MAG|

Parameters (definable at component level)

The following component-level parameters are definable for this model type and are listed on the Parameters tab of the Sim Model dialog. To access this dialog, simply double-click on the entry for the simulation model link in the Models region of the Component Properties dialog.

RATIO

turns ratio (secondary/primary).

RP

resistance of primary winding (in Ohms).

RS

resistance of secondary winding (in Ohms).

LEAK

leakage inductance (in Henrys).

MAG

magnetizing inductance (in Henrys).

Notes

A transformer is not one of the built-in SPICE engine models. It is a complex device and, as such, is defined using the hierarchical sub-circuit syntax.

All of the parameters will normally have a default value assigned. The default should be applicable to most simulations. Generally you do not need to change this value. Entering a value for a parameter on the Parameters tab of the Sim Model dialog will override its specified value in the sub-circuit file.

To check the default values of a transformer, open the appropriate sub-circuit (.ckt) file. You can view the content of this file for the model specified on the Model Kind tab of the Sim Model dialog, by clicking on the Model File tab at the bottom of the dialog. The default parameter values are listed in the .SUBCKT line.

Examples

Consider the transformer in the above image, with the following characteristics:

  • Pin1 (Pri+) is connected to net IN
  • Pin2 (Pri-) is connected to net GND
  • Pin3 (Sec+) is connected to A
  • Pin4 (Sec-) is connected to net C
  • Designator is TF1
  • The linked simulation sub-circuit file is 10TO1.ckt, with the following content:

*Transformer Subcircuit Parameters
*RATIO = Turns ratio= Secondary/Primary
*RP    = Primary DC resistance
*RS    = Secondary DC resistance
*LEAK  = Leakage inductance
*MAG   = Magnetizing inductance
*10:1 Transformer
*Connections:
*             Pri+
*             | Pri-
*             | | Sec+
*             | | | Sec-
*             | | | |
.SUBCKT 10TO1 1 2 3 4 PARAMS: RATIO=0.1 RP=0.1 RS=0.1 LEAK=1u MAG=1u
VISRC 9 4 DC 0V
FCTRL 6 2 VISRC {RATIO}
EVCVS 8 9 5 2 {RATIO}
RPRI  1 7 {RP}
RSEC  8 3 {RS}
LLEAK 7 5 {LEAK}
LMAGNET 6 5 {MAG}
.ENDS 10TO1

f no overriding parameters for the model are specified on the Parameters tab of the Sim Model dialog, then the default values listed in the sub-circuit definition will be used and the entries in the SPICE netlist would be:

*Schematic Netlist:
XTF1 IN 0 A C 10TO1
.
.
*Models and Subcircuit:
.SUBCKT 10TO1 1 2 3 4 PARAMS: RATIO=0.1 RP=0.1 RS=0.1 LEAK=1u MAG=1u
VISRC 9 4 DC 0V
FCTRL 6 2 VISRC {RATIO}
EVCVS 8 9 5 2 {RATIO}
RPRI  1 7 {RP}
RSEC  8 3 {RS}
LLEAK 7 5 {LEAK}
LMAGNET 6 5 {MAG}
.ENDS 10TO1

The Netlister will evaluate the formulae in the sub-circuit definition using the default parameter values, as defined in the 10TO1.ckt file.

You are reporting an issue with the following selected text and/or image within the active document: